1. 在電子表格里怎樣計算名次
使用RANK函數可以自動排名。
例如數據在B2:B11,(下面的例子）
在C1輸入函數=RANK(B2,$B$2:$B$11,1)，是對B列按升序排名次，
在D1輸入函數=RANK(B2,$B$2:$B$11)，是對B列按降序排名次，
在E1輸入函數=RANK(B2,$B$2:$B$11)+COUNTIF($B$2:B2,B2)-1，是對B列降序排列名次，並且不出現並列的情況。
輸入一個函數後點著單元格的右下角的小黑點，拖滑鼠到最後一行即可完成公式的填充。
CDE是各種情況的排列結果。
B C D E
56 1 9 9
78 8 3 3
56 1 9 10
83 9 2 2
59 3 8 8
66 4 5 5
66 4 5 6
94 10 1 1
77 7 4 4
66 4 5 7
2. EXCEL表格怎樣根據百分比自動排名
1、首先，打開Excel2010，輸入如圖所示數據。然後點擊第一個排名單元格，選擇RANK函數。
3. Excel 怎樣算排名
排名的函數
用排名函數來對成績進行排名，用起來非常地方便。
=IF(ISERR(RANK(M3,M:M)),"",RANK(M3,M:M))
A列是成績,B列是排名
=SUMPRODUCT((A$1:A$9>A1)/COUNTIF(A$1:A$9,A$1:A$9))+1
自動排名公式
=RANK(C3,$C$3:$C$12)
=RANK(A2,$A$2:$A$11,0)
=RANK(C2,$C$2:$C$65)+COUNTIF($C$2:C2,C2)-1
百分比排名的公式寫法為：
=PERCENTRANK($C$3:$C$12,C3)
平均分及總分排名
=AVERAGE(B2:E2)
=RANK(F2,$F$2:$F$65536)
求名次排名
統計成績時遇到一個分別求班級和年級總分名次排名的問題，不曉得應該運用什麼公式來實現。
班級名次：
=SUMPRODUCT((BJ=A2)*(ZF>E2))+1
年級名次：
=RANK(E2,ZF) 公式下拖。
排名次
根據總分值大小，只將姓名排序後, 降序結果
=INDEX(A$2:A$6,RANK(D2,D$2:D$6))
根據總分值大小，只將姓名排序後, 升序
=INDEX(A$2:A$6,RANK(D2,D$2:D$6,1))
根據分數進行普通排名
=RANK(A2,$A$2:$A$12)
=RANK(A2,A$2:A$12)+COUNTIF(A$2:A2,A2)-1
=SUMPRODUCT(1*($E$3:$E$12>=E3))
=RANK(K3,$K$3:$K$26)
=RANK(A2,A$2:A$12)
=SUM((A$2:A$12>=A2)/COUNTIF(A$2:A$12,A$2:A$12))
=COUNTIF($K$3:$K$26,">"&K3)+1
=INDEX($A$2:$A$7,MATCH(LARGE($C$2:$C$7,ROW(A1)),$C$2:$C$7,0),1)
=SUMPRODUCT(($A$2:$A$12>A2)/COUNTIF($A$2:$A$12,$A$2:$A$12&""))+1
=RANK(D2,OFFSET($A$1,MATCH($A2,$A:$A,0)-1,3,COUNTIF($A:$A,$A2),1))
對於普通排名分數相同時，按順序進行不重復排名
=RANK(K32,$K$32:$K$55)+COUNTIF($K$32:$K32,K32)-1
=COUNTIF($K$32:K32,K32)-1+COUNTIF($K$3:$K$26,">"&K32)+1
=SUMPRODUCT(1*(($E$3:$E$12+ROW($E$3:$E$12)/100>=($E3+ROW(E3)/100))))
=RANK(E3,$E$3:$E$12)+COUNTIF($E$3:E3,E3)-1
=SUMPRODUCT(1*(($E$3:$E$12+$B$3:$B$12/100)>=(E3+B3/100)))
依分數比高低名次成績排名
=RANK($E3,$E$3:$E$22) 內建方式排名
=SUMPRODUCT(1*($E$3:$E$12>=E3)) 一般方式排名
｛=RANK(E3,$E$3:$E$22)+SUM(IF($E$3:$E$22>E3,1/COUNTIF($E$3:$E$22,$E$3:$E$22),0))-COUNTIF($E$3:$E$22,">"&E3)｝ 一般方式排名
=RANK(E3,$E$3:$E$12)+COUNTIF($E$3:E3,E3)-1不重復排名
=SUMPRODUCT(1*(($E$3:$E$12+ROW($E$3:$E$12)/100>=($E3+ROW(E3)/100))))
=SUMPRODUCT(1*(($E$3:$E$12+$B$3:$B$12/100)>=(E3+B3/100)))不重復排名
=SUMPRODUCT(1*(($E$3:$E$12+$B$3:$B$12/100+$C$3:$C$12/10000)>=(E3+B3/100+C3/10000)))不重復排名
=RANK($E3,$E$3:$E$22,1)倒排序
美國式排名
=RANK(K247,$K$247:$K$270)
=RANK(B1,$B1:$H1)
中國式排名
=RANK(B2,$B$2:$B$21,0)
=RANK(B1,$B1:$H1)+COUNTIF($B$1:B1,B1)-1
=SUM(IF($A$1:$E$1>=A1,1/COUNTIF($A$1:$E$1,$A$1:$E$1),""))
=SUMPRODUCT(($B$2:$B$21>=B2)/COUNTIF($B$2:B$21,B$2:B$21))
=SUMPRODUCT((B$3:B$21>B3)*(1/COUNTIF($B$3:$B$21,$B$3:$B$21)))+1 （升序）
=SUMPRODUCT((B$3:B$21<B3)*(1/COUNTIF($B$3:$B$21,$B$3:$B$21)))+1 （降序）
｛=SUM(--(IF(FREQUENCY(B$2:B$21,B$2:B$21),B$2:B$21>B2)))+1｝
｛=SUM(IF($B$3:$B$21<=B3,"",1/(COUNTIF($B$3:B$21,B$3:B$21))))+1｝（升序）
｛=SUM(IF($B$3:$B$21<=B3,1/(COUNTIF($B$3:B$21,B$3:B$21)),""))｝（降序）
｛=SUM(IF($B$2:$B$21>B2,1/COUNTIF($B$2:B$21,B$2:B$21)))+1｝
｛=SUM(IF($A$1:$E$1>=A1,1/COUNTIF($A$1:$E$1,$A$1:$E$1),""))｝
｛=SUM(($B$2:$B$21>B2)*(MATCH($B$2:B$21,B$2:B$21,)=ROW($1:$20)))+1｝
｛=SUM(IF($B$1:$H$1<=B1,"",1/(COUNTIF($B$1:$H$1,$B$1:$H$1))))+1｝
求最精簡的自動排名公式
=RANK(E2,$E$2:$E$21)
=RANK(A2,$A$2:$A$9,0)
=RANK(A2,$A$2:$A$10)+COUNTIF($A$2:$A2,$A2)-1（如果數據列中數值有相同）
=RANK(F10,$F10:$Q10)+COUNTIF($F10:F10,F10)-1
=INDEX(A:A,1/MOD(LARGE(E$2:E$21+1/ROW($2:$21),ROW(1:1)),1))
=LOOKUP(1,0/(($F$2:$F$21=A27)*(COUNTIF(D$26:D26,$A$2:$A$21)=0)),$A$2:$A$21)=INDIRECT("A"&RIGHT(LARGE(($E$2:$E$21*100+ROW($A$2:$A$21)),ROW(A1)),2))
=RANK(C2,OFFSET($C$1,MATCH(E2,$E$2:$E$768,),,COUNTIF($E$2:$E$768,E2)))
數組公式
｛=INDEX(A:A,MOD(LARGE(E$2:E$21*100+ROW($2:$21),ROW(1:1)),100))｝
｛=OFFSET($A$1,RIGHT(LARGE($E$2:$E$21*1000+ROW($E$2:$E$21),ROW()-25),3)-1,,)｝
=OFFSET($A$1,RIGHT(LARGE(($E$2:$E$21*100+ROW($A$1:$A$20)),ROW(A3)),2),)
=TEXT(SUMPRODUCT(($E$2:$E$21>=E2)/COUNTIF($E$2:$E$21,$E$2:$E$21)),"第[DBNUM1]G/通用格式名")
排序後排名
｛=SUM(IF($B$2:$B$15>=B2,1/COUNTIF($B$2:$B$15,$B$2:$B$15)))｝
=SUMPRODUCT((B$2:B$15>=B2)/COUNTIF(B$2:B$15,B$2:B$15))
位次排名
｛=IF($B2:$O2>=0,RANK($B2:$O2,$B2:$O2,0),)｝
根據雙列成績進行共同排名
=RANK(C345,($C$345:$C$356,$H$345:$H$356))
在雙列間排名
=RANK(B2,($B$2:$B$26,$E$2:$E$16))
等次排名
由大到小排名
=RANK(B3,$B$3:$B$12)
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25>B16))+1
由小到大排名
=RANK(B3,$B$3:$B$12,1)
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25<B16))+1
不等次排名(行小排先）
由大到小
=RANK(B3,$B$3:$B$12)+COUNTIF($B$3:B3,B3)-1
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25-ROW($B$16:$B$25)/10000>B16-ROW(B16)/10000))+1
由小到大
=RANK(B3,$B$3:$B$12,1)+COUNTIF($B$3:B3,B3)-1
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25+ROW($B$16:$B$25)/10000<B16+ROW(B16)/10000))+1
不等次排名(行大排先）
由大到小
=COUNT($B$3:$B$12)-RANK(B3,$B$3:$B$12,1)-COUNTIF($B$3:B3,B3)+2
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25+ROW($B$16:$B$25)/10000>B16+ROW(B16)/10000))+1
由小到大
=COUNT($B$3:$B$12)-RANK(B3,$B$3:$B$12)-COUNTIF($B$3:B3,B3)+2
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25-ROW($B$16:$B$25)/10000<B16-ROW(B16)/10000))+1
順次排名
由大到小
=SUMPRODUCT((B$3:B$12>B3)*(1/COUNTIF(B$3:B$12,B$3:B$12)))+1
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25>B16)/COUNTIF($K$16:$K$25,$K$16:$K$25))+1
由小到大
=SUMPRODUCT((B$3:B$12<B3)*(1/COUNTIF(B$3:B$12,B$3:B$12)))+1
=SUMPRODUCT(($A$16:$A$25=A16)*($B$16:$B$25<B16)/COUNTIF($K$16:$K$25,$K$16:$K$25))+1
有並列排名
=RANK(B2,$B$2:$B$20)
=SUMPRODUCT(1*($B$3:$B$21>B3))+1
=COUNTIF($B$3:$B$21,">"&B3)+1
｛=SUM(IF($B$3:$B$21>B3,1,0))+1｝
=19-FREQUENCY($B$3:$B$21,B3)+1
=SUMPRODUCT(($B$2:$B$20>=B2)/COUNTIF($B$2:$B$20,$B$2:$B$20))
無並列排名
=RANK(B3,$B$3:$B$21)+COUNTIF($B$3:$B3,B3)-1
=SUMPRODUCT((B3-ROW()/1000<$B$3:$B$21-ROW($B$3:$B$21)/1000)*1)+1
=19-FREQUENCY($B$3:$B$21-ROW($B$3:$B$21)/1000,B3-ROW()/1000)+1
｛=SUM(IF($B$3:$B$21-ROW($B$3:$B$21)/1000>B3-ROW()/1000,1,0))+1｝
有並列分段排名
=SUMPRODUCT(($A$3:$A$21=A3)*($C$3:$C$21>C3))+1
=19-FREQUENCY(($A$3:$A$21=A3)*($C$3:$C$21),C3)+1
｛=MATCH(C3,LARGE(OFFSET($C$2,IF($A$3:$A$21=A3,ROW($A$3:$A$21)-2),),ROW(INDIRECT("1:"&COUNTIF($A$3:$A$21,A3)))),0)｝
｛=MATCH(C3,LARGE(IF($A$3:$A$21=A3,$C$3:$C$21),ROW(INDIRECT("1:"&COUNTIF($A$3:$A$21,A3)))),0)｝
｛=SUMPRODUCT(($A$3:$A$21=A3)*($C$3:$C$21>C3)/COUNTIF($N$3:$N$21,$N$3:$N$21))+1｝（需輔助列）
無並列分段排名
｛=SUMPRODUCT(($A$3:$A$21=A3)*($C$3:$C$21-ROW($C$3:$C$21)/10000>C3-ROW(C3)/10000))+1｝
=19-FREQUENCY(($A$3:$A$21=A3)*($C$3:$C$21-ROW($C$3:$C$21)/1000),C3-ROW()/1000)+1
成績排名
序號
姓名
語文
數學
英語
1
楊增海
135
136
146
2
郭愛玲
138
137
141
3
華志鋒
134
138
141
4
袁文飛
134
143
135
能否用一個公式直接找出所用考生中語文成績中第100名的成績是多少?
=LARGE(C2:C417,100)
=PERCENTILE(C2:C417,(416-100)/416)
=PERCENTILE($C$2:$C$417,(COUNTA($C$2:$C$417)-100)/COUNTA($C$2:$C$417))
能否用一個公式直接找出所用考生中語文成績中按與考人數的35%切線中位於第35%的成績是多少?
升冪
=SMALL(C2:C417,416*0.35)
=PERCENTILE($C$2:$C$417,0.35)
降冪
=LARGE(C2:C417,416*0.35)
=PERCENTILE($C$2:$C$417,1-0.35)
如何排名
1、對英語進行排名，缺考不計算在內。
2、對英語進行排名，缺考計算在內。
英語
英語排名
42
9
62
3
72
1
48
5
48
5
72
1
54
4
42
9
缺考
缺考
45
8
46
7
缺考不計算在內
b2=IF(A2="缺考","",RANK(A2,$A$2:$A$13))然後按照B列排序
缺考計算在內
=IF(A2="缺考",COUNTIF($A$2:$A$13,">=0")+1,RANK(A2,$A$2:$A$13))
=IF(A2="缺考",COUNT($A$2:$A$13)+1,RANK(A2,$A$2:$A$13,0))
數據排名（隔幾行排名）
=IF(A2="","",RANK(A2,$A$2:$A$11,0))
如果隔幾行排名，如下表，第五行、第九行和第十二行不參與排名。
單位
數據
排名
A
1
8
A
5
7
A
6
6
小計
12
B
8
4
B
9
3
B
7
5
小計
24
C
18
1
C
11
2
小計
29
=IF(A2="小計","",RANK(B2,(B$2:B$4,B$6:B$8,B$10:B$11))) 下拉
根據分數進行倒排名
=RANK($E3,$E$3:$E$22,1)
=RANK(K60,$K$60:$K$83,1)
=COUNTIF($K$60:$K$83,"<"&K60)+1
倒數排名函數是什麼
1為正排序，0為逆排序。
倒數排名=RANK(A2,$A$2:$A$5,0)
正數排名=RANK(A2,$A$2:$A$5,1)
如何實現每日各車間產量的排名
=RANK(C2,OFFSET($C$2:$C$5,MATCH(A2,$A$2:$A$1000,0)-1,,,))
=RANK(C2,OFFSET($C$2:$C$5,MATCH(A2,$A$2:$A$33,0)-1,,,))
分數相同時按照一科的分數進行排名
｛=MATCH(K308*100+D308,LARGE($K$308:$K$331*100+$D$308:$D$331,ROW($K$308:$K$331)-307),)｝
4. Excel排名變化。如圖，本月名次對比上月名次，在J 列要顯示出具體升降多少位，怎麼用公式自動計算出來。
在J3單元格中輸入公式
=IF(H3>I3,"↑",IF(H3=I3,"-","↓"))&IF(ABS(H3-I3),ABS(H3-I3),"")
下拉填充。
5. 電子表格怎樣自動排名次
RANK
請參閱
返回一個數字在數字列表中的排位。數字的排位是其大小與列表中其他值的比值（如果列表已排過序，則數字的排位就是它當前的位置）。
語法
RANK(number,ref,order)
Number 為需要找到排位的數字。
Ref 為數字列表數組或對數字列表的引用。Ref 中的非數值型參數將被忽略。
Order 為一數字，指明排位的方式。
如果 order 為 0（零）或省略，Microsoft Excel 對數字的排位是基於 ref 為按照降序排列的列表。
如果 order 不為零，Microsoft Excel 對數字的排位是基於 ref 為按照升序排列的列表。
說明
函數 RANK 對重復數的排位相同。但重復數的存在將影響後續數值的排位。例如，在一列按升序排列的整數中，如果整數 10 出現兩次，其排位為 5，則 11 的排位為 7（沒有排位為 6 的數值）。
由於某些原因，用戶可能使用考慮重復數字的排位定義。在前面的示例中，用戶可能要將整數 10 的排位改為 5.5。這可通過將下列修正因素添加到按排位返回的值來實現。該修正因素對於按照升序計算排位（順序 = 非零值）或按照降序計算排位（順序 = 0 或被忽略）的情況都是正確的。重復數排位的修正因素 =[COUNT(ref) + 1 – RANK(number, ref, 0) – RANK(number, ref, 1)]/2。在下列示例中，RANK(A2,A1:A5,1) 等於 3。修正因素是 (5 + 1 – 2 – 3)/2 = 0.5，考慮重復數排位的修改排位是 3 + 0.5 = 3.5。如果數字僅在 ref 出現一次，由於不必調整 RANK，因此修正因素為 0。
示例
如果您將示例復制到空白工作表中，可能會更易於理解該示例。
操作方法
創建空白工作簿或工作表。
請在「幫助」主題中選取示例。不要選取行或列標題。
從幫助中選取示例。按 Ctrl+C。
在工作表中，選中單元格 A1，再按 Ctrl+V。
若要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或在「工具」菜單上，指向「公式審核」，再單擊「公式審核模式」。
123456 A數據73.53.512公式說明（結果）=RANK(A3,A2:A6,1)3.5 在上表中的排位 (3)=RANK(A2,A2:A6,1)7 在上表中的排位 (5)
祝你成功！
6. 怎樣在EXCEL上排成績時顯示名次的升降（如+5或-30）
這個要在數據開始錄入時就准備
錄入數據時在每個成績行的尾部單元格輸入上次的排名。
錄入完成後進行本次成績的升序排列，然後在尾部單元格輸入本次排名（第1名那輸入1，第二名輸入2，然後直接下拉即可）
第一名成績尾部單元格輸入 =（單擊上次名次所在單元格）-（單擊本次名次所在單元格）回車（舉例見下方），然後下拉即可。
例：上次排名在M列，本次排名在N列，第一個成績行在第2行 則單元格O2中輸入「=M2-N2」
回車即可
7. 電子表格中如何自動排名
排序是數據處理中的經常性工作，Excel排序有序數計算（類似成績統計中的名次）和數據重排兩類。本文介紹Excel 2000/XP的數據排序方法。
一、數值排序
1.RANK函數
RANK函數是Excel計算序數的主要工具，它的語法為:RANK （number，ref，order），其中number為參與計算的數字或含有數字的單元格，ref是對參與計算的數字單元格區域的絕對引用，order是用來說明排序方式的數字（如果order為零或省略，則降序方式給出結果，反之按升序方式）。
需要注意的是:相同數值用RANK函數計算得到的序數（名次）相同，但會導致後續數字的序數空缺。
2.COUNTIF函數
COUNTIF函數可以統計某一區域中符合條件的單元格數目，它的語法為COUNTIF（range，criteria）。其中range為參與統計的單元格區域，criteria是以數字、表達式或文本形式定義的條件。其中數字可以直接寫入，表達式和文本必須加引號。
3.IF函數
Excel自身帶有排序功能，可使數據以降序或升序方式重新排列。如果將它與IF函數結合，可以計算出沒有空缺的排名。
二、文本排序
選舉等場合需要按姓氏筆劃為文本排序， Excel提供了比較好的解決辦法。
可以使用以下方法: 選中排序關鍵字所在列（或行）的首個單元格，單擊Excel「數據」菜單下的「排序」命令，再單擊其中的「選項」按鈕。選中「排序選項」對話框「方法」下的「筆畫排序」，再根據數據排列方向選擇「按行排序」或「按列排序」，「確定」後回到「排序」對話框。如果您的數據帶有標題行，則應選中「有標題行」（反之不選），然後打開「主要關鍵字」下拉列表，選擇其中的「單位」，選中排序方式（「升序」或「降序」）後「確定」，表中的所有數據就會據此重新排列。
此法稍加變通即可用於「第一名」、「第二名」等文本排序，請讀者自行摸索。
三、自定義排序
如果您要求Excel按照「金工車間」、「鑄造車間」和「維修車間」的特定順序重排工作表數據，前面介紹的幾種方法就無能為力了。這類問題可以用定義排序規則的方法解決:首先單擊Excel「工具」菜單下的「選項」命令，打開「選項」對話框中的「自定義序列」選項卡。選中左邊「自定義序列」下的「新序列」，游標就會在右邊的「輸入序列」框內閃動，您就可以輸入「金工車間」、 「鑄造車間」等自定義序列了，輸入的每個序列之間要用英文逗號分隔，或者每輸入一個序列就敲回車。如果序列已經存在於工作表中，可以選中序列所在的單元格區域單擊「導入」，這些序列就會被自動加入「輸入序列」框。無論採用以上哪種方法，單擊「添加」按鈕即可將序列放入「自定義序列」中備用。
使用排序規則排序的具體方法與筆劃排序很相似，只是您要打開「排序選項」對話框中的「自定義排序次序」下拉列表，選中前面定義的排序規則，其他選項保持不動。回到「排序」對話框後根據需要選擇「升序」或「降序」，「確定」後即可完成數據的自定義排序。
需要說明的是: 顯示在「自定義序列」選項卡中的序列（如一、二、三等），均可按以上方法參與排序，請讀者注意Excel提供的自定義序列類型。
如果第一種不能解決
用Excel巧排名次
許多公司企業為了加強管理，都要對內部各個部門定期進行量化評分考核並排列名次，激勵表現良好的部門，敦促改進落後部門，使公司管理不斷完善發展。面對無序的積分，在不改變各個部門原有位置的情況下給它們進行排列名次可是一件十分棘手的事件，尤其存在相同積分相同名次的排列更增加了難度。但如果能巧妙應用排位函數「Rank」及靈活應用Excel排序功能，問題解決起來也就比較簡單了。現以某鞋業有限公司的稽查評分總表(如圖1)為例來闡述解決方案。
在該稽查評分總表中，要根據總評分欄的積分在不改變各個部門原有位置的情況下求出各部門相應的名次。總評分最高者名次為1，然後隨總評分遞減而名次加1。若總評分相同則名次也相同，但該名次之後的部門名次仍然按該名次加1計算，例如有3個第4名則第4名後就緊跟第5名。
1.應用Rank函數進行排位
用游標選定D4單元格後輸入「=RANK(C4,$C$4:$C$26)」按回車鍵後便可計算出第一記錄的「名次」。將游標移到E3單元格填充柄上變成細十字形游標後，按下滑鼠左鍵往下拖(公式復制)，就可將所部門的「名次」計算出來(說明：以上公式中$C$4:$C$26是指絕對引用C4到C26單元格區域)。
雖然Rank函數已將所有的部門按積分的高低進行名次排列，但在相同名次的後面的名次卻沒有達到我們的要求。如在本例中有兩個第1名而後面出現的並不是我們期待的第2名而是第3名。為此，我們還得巧妙地應用排序功能來補充完成Rank函數尚未完成的工作。
2.增加關鍵欄位
為了保證各部門位置不變，我們可以藉助增加關鍵欄位再將其隱藏的方法來處理，具體操作如下：分別選定第D列和第F列點擊「插入」菜單並單擊「列」後便可自動增加2列(圖2)。選定D3單元格輸入一個新欄位名「序列」，再選定D4單元格並輸入1，將游標移到在D4單元格填充柄上變成細十字形游標後按住「Ctrl鍵」不放，並按下滑鼠左鍵往下拖至D26後松開，這時在D4到D26出現從1到23的序列填充。將E3單元格的欄位名改為「名次1」並在F3單元格輸入欄位名「名次」。
3.根據需要進行相關排序
將游標選定在表格內任一單元格內，點擊「數據」菜單→「排序」→在「主要關鍵字」下拉框內選定「名次1」並選定「遞增」單選鈕→確定。在F4單元格內輸入1後將游標選定在F5單元格後輸入「=IF(E4=E5,F4,F4+1)」，按回車鍵，然後依照上述方法將F5的公式復制到F26。為了還原有各部門的相關位置，依照前面排序方法再進行一次排序，但「主要關鍵字」則必須改為按「序列」欄位進行遞增排序。可是這時卻發現經排序後的前幾個記錄卻以「#VALUE!」的形式出現，這是因為「名次」欄位的公式計算結果經排序後產生錯誤的緣故，為此，必須在「序列」欄位排序之前將「名次」欄位的公式計算結果轉為數值常量後再進行排序。操作如下：選定E4到E26單元格區域→單擊工具欄上復制命令按鈕→點擊「編輯」菜單→選定「選擇性粘貼」→在彈出的對話框內選定「數值」單選鈕確定後即可。最後依次選定D列、E列→點擊「格式」菜單→列→隱藏「列」便可得到我們所要的效果了。
8. excel自動計算排名
D2=IF(E2="","",INDIRECT("A"&MATCH(E2,B:B,0)))
E2=IF(ISERR(LARGE(B:B,ROW(A1))),"",LARGE(B:B,ROW(A1)))
F2=IF(E2="","",ROW(A2)-1)
將以上單元格的公式向下復制就行了。